all repos — min @ 1afdcd2063a3664a3f0ca05872fb0de9ee07355f

A small but practical concatenative programming language.

minpkg/lib/min_time.nim

 1
 2
 3
 4
 5
 6
 7
 8
 9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 
import
  std/times
import
  ../core/parser,
  ../core/value,
  ../core/interpreter,
  ../core/utils

proc time_module*(i: In) =
  let def = i.define()

  def.symbol("stamp") do (i: In):
    i.push getTime().toUnix().newVal

  def.symbol("now") do (i: In):
    i.push epochTime().newVal

  def.symbol("info") do (i: In):
    let vals = i.expect("num")
    let t = vals[0]
    var time: Time
    if t.kind == minInt:
      time = t.intVal.fromUnix
    else:
      time = t.floatVal.int64.fromUnix
    let tinfo = time.local
    var info = newDict(i.scope)
    info.objType = "timeinfo"
    i.dset info, "year", tinfo.year.newVal
    i.dset info, "month", (tinfo.month.int).newVal
    i.dset info, "day", tinfo.monthday.newVal
    i.dset info, "weekday", (tinfo.weekday.int+1).newVal
    i.dset info, "yearday", tinfo.yearday.newVal
    i.dset info, "hour", tinfo.hour.newVal
    i.dset info, "minute", tinfo.minute.newVal
    i.dset info, "second", tinfo.second.newVal
    i.dset info, "dst", tinfo.isDST.newVal
    i.dset info, "timezone", tinfo.utcOffset.newVal
    i.push info

  def.symbol("to-timestamp") do (i: In):
    let vals = i.expect("dict:timeinfo")
    let dict = vals[0]
    try:
      let year = i.dget(dict, "year").intVal.int
      let month = Month(i.dget(dict, "month").intVal.int)
      let monthday = MonthdayRange(i.dget(dict, "day").intVal.int)
      let hour: HourRange = i.dget(dict, "hour").intVal.int
      let minute: MinuteRange = i.dget(dict, "minute").intVal.int
      let second: SecondRange = i.dget(dict, "second").intVal.int
      let timezone = i.dget(dict, "timezone").intVal.int
      let tinfo = dateTime(year, month, monthday, hour, minute, second, 0, utc())
      i.push (tinfo + timezone.seconds).toTime.toUnix.int.newVal
    except CatchableError:
      raiseInvalid("An invalid timeinfo dictionary was provided.")

  def.symbol("datetime") do (i: In):
    let vals = i.expect("num")
    let t = vals[0]
    var time: Time
    if t.kind == minInt:
      time = t.intVal.fromUnix
    else:
      time = t.floatVal.int64.fromUnix
    i.push time.utc.format("yyyy-MM-dd'T'HH:mm:ss'Z'").newVal

  def.symbol("format") do (i: In):
    let vals = i.expect("str", "num")
    let s = vals[0]
    let t = vals[1]
    var time: Time
    if t.kind == minInt:
      time = t.intVal.fromUnix
    else:
      time = t.floatVal.int64.fromUnix
    i.push time.local.format(s.getString).newVal

  def.finalize("time")